SUBROUTINE Extract_RA159S

c Subroutine to extract APN-159 Synchro Radar Altimeter data
c     into common
c   Adjusts 10 samples up to 40

      IMPLICIT none

      INCLUDE "FastCom.ftni"

C Local storage
      INTEGER i, Ptr_lcl, IRaw
      REAL Coarse, RA_Temp, RA, Cab_Len
      PARAMETER (Cab_Len=-36.04) ! acft antenna cable length

      DO i = 1,40  ! flag all locations as bad
        Alt(i) = -999.
      END DO
      
C Move all good samples to the array, spaced out
      IF (Dig_Size(6).EQ.10) THEN  ! should be 10 samples, or else bad
        Ptr_lcl = 2  ! first Alt() loc to fill
        DO i = Dig_Start(6),Dig_Start(6)+9  ! # of 16 bit samples
          IRaw = IB(i)
          Coarse = FLOAT( IAnd(IRaw,Z'F000')/4096 )*3125. - 400.
          RA_Temp = FLOAT( IAnd(IRaw,Z'0FFF') ) * (4000./4096.)
          DO WHILE (RA_Temp.LT.Coarse)
            RA_Temp = RA_Temp + 4000.
          END DO
          Alt(Ptr_lcl) = RA_Temp + Cab_Len
          Ptr_lcl = Ptr_lcl + 4
        END DO
        CALL LinFilt(Alt,100.,'   Alt')  ! fill in the rest

        RA_OK = .TRUE.  ! show we filled RA
      ENDIF

      RETURN

      END